My radiology script

Download AHK and SciTE4AHK (text editor) to write your own scripts, or use my script and script runner by downloading them into the same folder and running radiology.exe.

Download Autohotkey and SciTE4AHK Download my script (radiology.ahk) and script runner (radiology.exe)

My script code:

#SingleInstance force
#Requires Autohotkey v2
CoordMode "ToolTip", "Screen"
CoordMode "Mouse", "Client"
SetTitleMatchMode 2

; Variable Definitions
USER := ""
PASS := ""
KEEPAWAKE := 0
EPIC_TITLE := "Prod"
PS := "360"
RADSMODE := false
PSEDITCTL := ""

; GUI Initialization
myGui := Gui()
myGui.Add("GroupBox", "x16 y0 w450 h67", "Login Information")
myGui.Add("Text", "x24 y24 w56 h23 +0x200", "Username:")
myGui.Add("Text", "x248 y24 w53 h23 +0x200", "Password:")
Edit1 := myGui.Add("Edit", "x88 y24 w134 h21")
Edit2 := myGui.Add("Edit", "x312 y24 w133 h21 +Password")
LaunchButton := myGui.Add("Button", "x16 y80 w444 h61", "Launch and Minimize Window").OnEvent("Click", LaunchButtonHandler)
myGui.Add("Text", "x16 y184 w399 h23 +0x200", "This launcher will minimize after site selection. Close the window to kill the script.")
myGui.Add("Text", "x16 y208 w360 h23 +0x200", "Alt + b = break the glass                Alt + p = enter username and password")
CheckBox1 := myGui.Add("CheckBox", "x184 y152 w130 h23", "Prevent Sleep")
Edit1.OnEvent("Change", OnEventHandler)
Edit2.OnEvent("Change", OnEventHandler)
CheckBox1.OnEvent("Click", OnEventHandler)
myGui.Title := "AutoHotkey Login Script"
myGui.OnEvent("Close", CloseHandler)
myGui.Show("w478 h235")

; GUI Handlers
OnEventHandler(*) {
    global USER := Edit1.Value
    global PASS := Edit2.Value
    global KEEPAWAKE := CheckBox1.Value
}

LaunchButtonHandler(*) {
    If not WinExist(PS) {
        Run("C:\Program Files\Nuance Communications\NextGen Communicator\Communicator.exe")
    }
    myGui.Minimize()
}

CloseHandler(*) {
    MsgBox("Script closed.")
    ExitApp
}

; Background Timers
SetTimer StopSleep, 100000 ; Every 100 seconds
SetTimer UpdatePSEditWindow, 1000 ; Check every second

; Functions
breakGlass() {
    If WinExist(EPIC_TITLE) {
        WinActivate(EPIC_TITLE)
        Sleep(100)
        Send("Care")
        Sleep(200)
        Send("{Enter}")
        Sleep(200)
        Send("{Tab}")
        Sleep(100)
        Send("{Tab}")
        Sleep(100)
        Send("{Raw}" PASS)
        Sleep(200)
        Send("!A")
    }
}

loginSite() {
    Send("{Raw}" USER)
    Sleep(200)
    Send("{Tab}")
    Sleep(200)
    Send("{Raw}" PASS)
    Sleep(200)
    Send "{Enter}"
}

StopSleep(*) {
    if (KEEPAWAKE) {
        Send("{F15}")
    }
}

UpdatePSEditWindow() {
    global PSEDITCTL
    if (WinExist(PS) && !PSEDITCTL) {
        ClassNNs := WinGetControls(PS)
        for index, item in ClassNNs {
            if InStr(item, "RICHEDIT") {
                PSEDITCTL := item
                return
            }
        }
    }
}

toggleRadMode(*) {
    global RADSMODE
    RADSMODE := !RADSMODE
    TooltipMessage := (RADSMODE ? "Rads Mode: on" : "Rads Mode: off")
    ToolTip(TooltipMessage, RADSMODE ? 500 : 0, 0)
}

genericControlSend(action, key) {
    if (RADSMODE) {
        WinActivate(PS)
        ControlSend(action, PSEDITCTL, PS)
    } else {
        Send(key)
    }
}

toggleDictation(*) {
    genericControlSend("{F4}", "d")
}

nextField(*) {
    genericControlSend("{Tab}", "f")
}

prevField(*) {
    genericControlSend("{Shift down}{Tab}{Shift up}", "g")
}

backspace(*) {
    genericControlSend("{Backspace}", "s")
}

newLine(*) {
    genericControlSend("{Enter}", "a")
}

exitRadsMode(*) {
    if (RADSMODE) {
        toggleRadMode()
    }
}

getFieldStrength(*) {
    Send("^d")
    Sleep(500)
    Send("field{Enter}")
}

enableRadsMode(*) {
    global RADSMODE := true
    TooltipMessage := "Rads Mode: on"
    CoordMode "ToolTip", "Screen"
    ToolTip(TooltipMessage, 500, 0)
}

saveDraft(*) {
    genericControlSend("{F9}", "h")
}

pick(num, action) {
    ; TODO make a return mouse function based on relative coords to last window
    if (RADSMODE) {
		CoordMode "Mouse", "Screen"
		MouseGetPos &xpos, &ypos
		CoordMode "Mouse", "Client"
        heightRow := 20
        for n, ctrl in WinGetControls("PowerScribe")
        {
            if (ControlGetText(ctrl, "PowerScribe") == "Pick List Choices") {
                ControlGetPos(&x, &y, &w, &h, ctrl, "PowerScribe")
                pos := y + Integer(heightRow/2) + heightRow * num
                WinActivate("PowerScribe")
                MouseMove x+20, pos
                Click 2
				CoordMode "Mouse", "Screen"
				MouseMove xpos, ypos
                nextField()
				return
        }
        }

} else {
        Send(action)
    }
}

normal(*) {
    if (RADSMODE) {
        WinActivate(PS)
        Send("Normal")
        Sleep(100)
        nextField()
    } else {
        Send("r")
    }
}

searchBiopsy(*) {
    WinActivate(EPIC_TITLE)
    Send("^{Space}")
    Sleep(200)
    Send("Biopsy")
    Sleep(200)
    Send("{Enter}")
    }

; Hotkey Bindings
$CapsLock::Ctrl
!b:: breakGlass()
!p:: loginSite()
!d:: getFieldStrength()
!f:: searchBiopsy()

!Space:: enableRadsMode()
$^d:: exitRadsMode()

$d:: toggleDictation()
$h:: saveDraft()
$f:: nextField()
$g:: prevField()
$s:: backspace()
$a:: newLine()
$e:: pick(2, "e")
$r:: normal()